写了一点龙芯1C102的入门导读...

Czitong

序

龙芯推出1系列芯片102、103两款也有一年时间了，看到网上相关资料还是寥寥无几，决定还是入手写一点东西发出来作为分享和记录，本文是笔者和同事@snow 在102开发过程中的一些经验，因为我们也是第一次使用龙芯MCU,有很多不足之处也欢迎各位大佬补充🙏🙏
本文档旨在厘清以1C102号芯片(以下简称102)为例的示例代码功能及结构，以帮助开发者可以快速入手1系列芯片进行开发工作。
本文主要章节有：

102号芯片资源介绍。
相关资料获取渠道。
《ls1x-master-v0.4》代码结构导读。
Start.s启动流程。
中断处理流程。
一次完整的代码编译、烧录流程示例。

Demo代码实现了102芯片使用过程中一些简单的库函数，完备的映射关系，并对调用关系进行了简单的举例，最后实现了一个基于102芯片为核心的开发板的命令行功能，可以进行部分模块的调用，是一个入门者友好的示例代码。因此本文选择使用该示例进行介绍，以补充102芯片开发相关的资料及经验。
因为笔者也是第一次接触龙芯MCU,很多坑也是开发过程中踩出来的，仍有很多需要完善和补充的地方，如有错误，还请联系笔者订正。

注：如果您的手上有102开发的.bin文件，可以直接学习第6章以快速使用龙芯1系列芯片。

Czitong

第1章 102号芯片资源介绍

龙芯1C102是一款嵌入式领域定制的芯片产品，主要面向智能家居以及其他物联网设备，采用龙芯LA132处理器核心，该芯片集成Flash、SPI、UART、I2C、RTC、TSENSOR、VPWM、ADC、GPIO等功能模块，在满足低功耗要求的同时，大幅减少板级成本，具有高稳定、高安全、低成本等特点。产品主要应用于智能门锁类产品、电动助力车、跑步机等。(来源于龙芯官网的介绍)
由于开发者可以很轻松的获取该芯片的中文用户手册及数据手册，所以仅对笔者认为重要的硬件资源做简单介绍，详细内容请参考用户手册：

32位单发射LA132处理器核。
4KB SRAM(指令) + 4KB SRAM(数据)
主频8MHz、10.6MHz,RAM取指速度32MHz.

Czitong

第2章相关资料获取渠道

102号芯片用户手册及芯片手册：
102处理器用户手册
 102处理器数据手册
《ls1x-master-v0.4》代码获取：
gitea获取代码
LoongArch平台编译工具链：
gitea平台获取编译工具链
该工具链支持了用户在龙芯平台上对代码进行编译开发，也是笔者目前的开发环境，后面的介绍将默认在loongarch环境下进行。
龙芯嵌入式开发工具(IDE,笔者未验证，仅作为资料提供)：
LoongIDE

Czitong

第3章《ls1x-master-v0.4》代码结构导读

该源码包含ls1c102的代码以及ls1c103的代码，我们使用的是ls1c102的源码部分

Czitong

第4章 Start.s启动流程

在build的ld文件中可以看见ls1c102的ld链接脚本，由脚本可以知道程序入口是_start。该函数定义在target/start.S中，这也是MCU上电后执行的第一行指令的入口。我们先看start.S中的代码，这里只摘取关键部分.由于代码是汇编，所以看时可以参考龙芯架构32位精简版参考手册

_start:
        #这里参考ld链接脚本可知，是将_sidata开始的数据，拷贝到_sdata处长度为_edata-_sdata.其主要内容是got,plt以及一些指定了默认值的全局变量
        move     t1 , zero
        b    LoopCopyDataInit
CopyDataInit:
        la.abs   t3, _sidata
        add.w    t4, t3, t1
        ld.w     t3, t4, 0x0
        add.w    t4, t0, t1
        st.w     t3, t4, 0x0
        addi.w   t1, t1, 0x4
LoopCopyDataInit:
        la.abs   t0, _sdata
        la.abs   t3, _edata
        add.w    t2, t0, t1
        bne      t2, t3, CopyDataInit

        #下面是将bss区域清零。这里主要存放的是一些没有指定初始化数据的全局变量（ls1c102的此固件不支持malloc之类的操作，所以bss的空间基本上就是由用户写代码时定义的没有赋予初值的全局变量使用）
        la.abs  t0, _sbss
        la.abs  t1, _ebss
        beq     t1, t0, cpu_init_start
LoopFillZerobss:
        st.w    zero, t0, 0
        addi.w  t0, t0, 4
        bne t1, t0, LoopFillZerobss

cpu_init_start:
        #这里开始了MCU的初始化操作
        #首先这里设置了MCU的异常处理地址为0x1c001000
### reset normal exception base and Ex config
        li.w      t0, 0x1c001000
        csrwr     t0, CSR_EBase
        li.w      t0, (0<<S_CSR_ExConfig_VS)|(0x0000<<S_CSR_ExConfig_IM) # 4 instruction gap
        csrwr     t0, CSR_ExConfig

        #这里对中断掩码进行了设置，这个过程中csrwr以及csrxchg等指令操作的寄存器参考龙芯架构32位精简版参考手册的控制状态寄存器
//        li.w      t0, 0x1fff
        li.w      t0, 0x1ffc
        csrxchg t0, t0, CSR_ExConfig
        #下面的CSR_SEGCA和CSR_SEGPA寄存器没有找到说明，只能通过原代码注释自行理解了
    ##set VSEG4(0x80000000~0x9fffffff) to cached, other VSEG to uncached
        li.w      t0, CACHE_OP
        csrwr     t0, CSR_SEGCA
    ##set VSEG4(0x80000000~0x9fffffff) to PSEG0(0x00000000~0x1fffffff), other VSEG unchanged
        li.w      t0, ADDR_MAP
        csrwr     t0, CSR_SEGPA
    ##set DA=0(change DA-mode to AD-mode)
        li.w      t0, 0x8
        csrxchg   zero, t0, CSR_CRMD

        #设置栈寄存器，这里SP_BASE是（0x80002000-132），设置玩栈寄存器后就有了C语言运行的条件，于是跳转进main函数开始执行c代码
        li.w    sp, SP_BASE
        bl      main

        #main函数如果退出的话程序将在此处死循环，这里ra的值是上一条指令bl跳转进main函数时由硬件填入的bl吓一跳指令的地址，即当前指令的地址，实现了一直原地跳转死循环
        jirl      zero, ra, 0

        #这时一个可以被外部调用的让处理器核停止取指进入等待状态的函数，关键指令为idle，该指令在龙芯架构32位精简版参考手册有介绍
        .globl cpu_wait
cpu_wait:
        idle 0
        jr      ra

Czitong

第5章中断处理流程

在前面的start.S的启动流程分析中，有提及到将MCU的异常处理地址设置为了0x1c001000，由于ls1c102的硬件设计，其启动地址为0x1c000000,所以中断处理的入口地址就在start.S内的.org 0x1000处，内容如下：

#该宏定义了将中断现场保存进指定内存空间的操作
#define SAVE_REGS_FAST(BASE) \
    #这里由于所有寄存器都存放了中断现场的值，不能进行破坏，所以使用了csr寄存器去临时作为保存空间，可以空出一个寄存器以便使用
    csrwr   tp, CSR_KScratch1; \
        #这里设置保存中断现场的基地址并将寄存器数据全部写入内存空间进行保存
        li.w    tp, BASE;\
        st.w    t0, tp, -0x4 ;\
        st.w    t1, tp, -0x8 ;\
        st.w    t2, tp, -0xc ;\
        st.w    t3, tp, -0x10;\
        st.w    t4, tp, -0x14;\
        st.w    t5, tp, -0x18;\
        st.w    t6, tp, -0x1c;\
        st.w    t7, tp, -0x20;\
        st.w    t8, tp, -0x24;\
        /*st.w    s0, tp, -0x28;*/\
        /*st.w    s1, tp, -0x2c;*/\
        /*st.w    s2, tp, -0x30;*/\
        /*st.w    s3, tp, -0x34;*/\
        /*st.w    s4, tp, -0x38;*/\
        /*st.w    s5, tp, -0x3c;*/\
        /*st.w    s6, tp, -0x40;*/\
        /*st.w    s7, tp, -0x44;*/\
        /*st.w    s8, tp, -0x48;*/\
        st.w    a0, tp, -0x4c;\
        st.w    a1, tp, -0x50;\
        st.w    a2, tp, -0x54;\
        st.w    a3, tp, -0x58;\
        st.w    a4, tp, -0x5c;\
        st.w    a5, tp, -0x60;\
        st.w    a6, tp, -0x64;\
        st.w    a7, tp, -0x68;\
        st.w    ra, tp, -0x6c;\
        st.w    sp, tp, -0x70;\
        /*st.w    gp, tp, -0x74;*/\
        /*st.w    fp, tp, -0x78;*/\

#该宏定义了将保存的中断现场进行恢复的操作
#define RESTORE_REGS_FAST(BASE) \
        #获取保存地址并逐一恢复保存的寄存器值
        li.w    tp, BASE;\
        ld.w    t0, tp, -0x4 ;\
        ld.w    t1, tp, -0x8 ;\
        ld.w    t2, tp, -0xc ;\
        ld.w    t3, tp, -0x10;\
        ld.w    t4, tp, -0x14;\
        ld.w    t5, tp, -0x18;\
        ld.w    t6, tp, -0x1c;\
        ld.w    t7, tp, -0x20;\
        ld.w    t8, tp, -0x24;\
        /*ld.w    s0, tp, -0x28;*/\
        /*ld.w    s1, tp, -0x2c;*/\
        /*ld.w    s2, tp, -0x30;*/\
        /*ld.w    s3, tp, -0x34;*/\
        /*ld.w    s4, tp, -0x38;*/\
        /*ld.w    s5, tp, -0x3c;*/\
        /*ld.w    s6, tp, -0x40;*/\
        /*ld.w    s7, tp, -0x44;*/\
        /*ld.w    s8, tp, -0x48;*/\
        ld.w    a0, tp, -0x4c;\
        ld.w    a1, tp, -0x50;\
        ld.w    a2, tp, -0x54;\
        ld.w    a3, tp, -0x58;\
        ld.w    a4, tp, -0x5c;\
        ld.w    a5, tp, -0x60;\
        ld.w    a6, tp, -0x64;\
        ld.w    a7, tp, -0x68;\
        ld.w    ra, tp, -0x6c;\
        ld.w    sp, tp, -0x70;\
        /*ld.w    gp, tp, -0x74;*/\
        /*ld.w    fp, tp, -0x78;*/\
    csrrd   tp, CSR_KScratch1;

    .org 0x1000
DEFAULT_INT_HANDLER:
    #此处在处理中断前先对中断现场进行了保存，即保存各寄存器的至，该宏定义的展开在上面，这里的REGS_MEM为0x80002000，结合上面设置栈寄存器时的地址，可以理解为此空间是在栈底高地址区域特地留下来用于保存中断现场的空间
    SAVE_REGS_FAST(REGS_MEM)
        csrrd   t0, CSR_ExStatus
        andi    t1, t0, INT_VECTOR
        beqz    t1, exception_core_check
exception_pmu:
        andi    t1,t0,0x1
        bnez    t1,sw0_label

        andi    t1,t0,0x2
        bnez    t1,sw1_label

        andi    t1,t0,0x4
        bnez    t1,wake_label

        andi    t1,t0,0x8
        bnez    t1,touch_label

        andi    t1,t0,0x10
        bnez    t1,uart2_label

        andi    t1,t0,0x20
        bnez    t1,bcc_label

        andi    t1,t0,0x80
        bnez    t1,exint_label

        andi    t1,t0,0x800
        bnez    t1,timer_label

sw0_label:
        bl      Software0_HANDLER
        b       exception_exit

sw1_label:
        bl      Software1_HANDLER
        b       exception_exit

wake_label:
        bl      TIMER_WAKE_INT
        b       exception_exit

touch_label:
        bl      TOUCH
        b       exception_exit

uart2_label:
        bl      UART2_INT
        b       exception_exit

bcc_label:
        bl      BAT_FAIL
        b       exception_exit

exint_label:
        bl      ext_handler
        b       exception_exit

timer_label:
        bl      TIMER_HANDLER
        b       exception_exit

exception_core_check:
        andi    t1, t0, INTC_VECTOR
        beqz    t1, exception_exit
        bl      intc_handler
        b       exception_exit

exception_exit:
    RESTORE_REGS_FAST(REGS_MEM)
    ertn

根据龙芯架构32位精简版参考手册的解释我们可知
在中断触发时：

将 CSR.CRMD 的 PLV、IE 分别存到 CSR.PRMD 的 PPLV、PIE 中，然后将CSR.CRMD的PLV置为 0，IE 置为 0
将触发例外指令的 PC 值记录到 CSR.ERA 中
跳转到例外入口处取指

当软件执行 ertn 指令从例外执行返回时：

将 CSR.PRMD 中的 PPLV、PIE 值恢复到 CSR.CRMD 的 PLV、IE 中
跳转到 CSR.ERA 所记录的地址处取指。

Czitong

第6章一次完整的代码编译、烧录流程示例

代码编译环境

CPU：Loongson-3C5000
系统：AOSC OS（新世界）

代码的编译

在下载好v0.4的demo代码和编译工具链后就可以开始准备编译。
编译前需要设置交叉编译器的路径，方式如下：

打开build/Makefile文件。
修改CROSS_COMPILE变量为编译器的路径，例如/home/snow/myself/1c102/loongson-gnu-toolchain-8.3/bin/loongarch32-linux-gnuf64-。

在修改好交叉工具链路径后就可以使用make 1c102编译生成ls1c102的demo固件。
编译成功之后用于烧录的固件位于build/1c102_demo.bin。

这其中还有一些编译产生的中间文件对我们后期调试会有帮助，如build/1c102_demo.s，该文件是固件的反汇编文件，里面是可以阅读的汇编代码。
清除编译可以使用make clean命令。

固件的烧录

目前有两种固件烧录方法，一种是通过JTAG或者烧录夹具向FLASH区域内烧录固件，然后使MCU通过SPI总线读取FLASH中的数据启动。这种方式的优点是烧录设备较容易获得，缺点是MCU的运行受限于SPI总线的数据读取速度，肯定比片内flash运行要慢一些。
另一种方式是使用龙芯公司提供的EJTAG/JTAG仿真器，这个仿真器内置了烧录工具，可以对片内flash进行烧录，也可以读取任意寄存器的值，以实现对MCU的简单调试。(虽然实际开发过程中还是看反汇编和printf多一些...)。这种方式的优点是片内运行更稳定，更快。但是缺点也显而易见就是EJTAG不好搞，固件大小也被限制在128K以内。
因为笔者有EJTAG设备，所以对方法2进行介绍，后面有机会补充JTAG的烧录方法。(主要是没有开发板...)
通过串口工具(波特率115200,8N1)与ejtag进行交互，进入系统你会看到文件系统根目录，切入到/tmp/ejtag-debug目录中，看到如下目录结构：
|— bin：存放了不同mcu的SPI下载bin文件。因此可知EJTAG也可以往外部SPI FLASH中烧录代码。
|— configs：不同MCU的配置文件。
|_ la_dbg_tool_gpio：LA架构MCU的烧录调试工具。

将要烧录的文件传到本目录下(minicom可用AS功能传输，EJTAG也提供以太网传输文件的功能，可以使用python搭建一个简易的ftp服务传输文件。)
进入烧录工具/tmp/ejtag-debug # ./la_dbg_tool_gpio -t，可以使用jtagregs d4 1 1查看MCU状态，若MCU上电则显示5a5a5a5a，表示MCU工作正常。
执行source configs/config.la1c102配置102，有两种烧录命令，一种是program_flash烧录内部flash,后接要烧录的固件名称。另一种是program_spi烧录spi flash,后接上同。
然后就是等待程序烧录完成，烧录完成后程序会进行checksum工作，显示check done表示校验通过，烧录完成。重启芯片后MCU即跑新烧录的程序了。

固件生成流程

生成ls1c102固件我们首先需要执行make 1c102这条指令，在项目根目录下的Makefile中很容易可以知道会执行如下内容：

MCU := 1c102
MCU += 1c103

$(MCU):
    @echo "***************************************************************************"
    @echo "*"
    @echo "*    Welcome loongson $(@)"
    @echo "*    You will get one file in /home/tftpboot or ./ ."
    @echo "*    This is $(@).bin."
    @echo "*"
    @echo "***************************************************************************"
    make BOARD=$(@) -C build clean
    make BOARD=$(@) -C build all

这里会调用在build下的Makefile,这个Makefile才是主要的文件。首先我们来分析make BOARD=$(@) -C build clean命令。
在build下的Makefile中有如下内容：

clean :
    rm -rf *.o *.elf *.map *.bin *.s *.a

这条语句执行的是clean的操作，所以我们在重新编译的时候可以直接执行make 1c102命令，项目会先自动清除一遍。接着我们来看make BOARD=$(@) -C build all命令。
这里摘取重要内容

##这里我们的BIARD是1c102,在上面的执行命令可以知道
ifeq ($(BOARD),1c102)
  BOARDNAME = LS1C102
  IMAGENAME = 1c102_demo
else ifeq ($(BOARD),1c103)
  BOARDNAME = LS1C103
  IMAGENAME = 1c103_demo
endif

/*
到这里可知  
BOARDNAME = LS1C102
IMAGENAME = 1c102_demo
*/

##到这里可知IMAGE_BIN的值为1c102_demo.bin.  
IMAGE_BIN = $(IMAGENAME).bin

/*
下面是生成依赖文件的一系列操作
*/
BUILD_DIR = $(ROOT_DIR)/build
TARGET    = $(ROOT_DIR)/target
PUBLIC    = $(ROOT_DIR)/public
USER      = $(ROOT_DIR)/user

ifeq ($(BOARD),1c102)
BOARDNAME = LS1C102
IMAGENAME = 1c102_demo
else ifeq ($(BOARD),1c103)
BOARDNAME = LS1C103
IMAGENAME = 1c103_demo
endif
PRIVATE   = $(ROOT_DIR)/private/ls$(BOARD)
CASE      = $(ROOT_DIR)/private/ls$(BOARD)/case
BCMDLINE  = $(ROOT_DIR)/user/$(BOARD)_cmdline.o
BCOMMAND  = $(ROOT_DIR)/user/$(BOARD)_cmd.o
BINT      = $(ROOT_DIR)/user/$(BOARD)_Interrupt.o

SRCDIR    = $(TARGET) $(PUBLIC) $(PRIVATE) $(CASE)

SRC_C  = $(foreach dir, $(SRCDIR), $(wildcard $(dir)/*.c))
SRC_S  = $(foreach dir, $(SRCDIR), $(wildcard $(dir)/*.S))
SRC    = $(SRC_C) $(SRC_S)
OBJ_C  = $(notdir $(patsubst %.c, %.o, $(SRC_C)))
OBJ_C += $(notdir $(BCMDLINE))
OBJ_C += $(notdir $(BCOMMAND))
OBJ_C += $(notdir $(BINT))
OBJ_S  = start.o $(filter-out start.o, $(notdir $(patsubst %.S, %.o, $(SRC_S))))
LS1C1X_OBJ = $(OBJ_S) $(OBJ_C)
VPATH     = $(SRCDIR) $(USER)

/*
以上的操作完成后，LS1C1X_OBJ变量里面就是一系列.c和.S文件对应的.o文件,最终编译生成后放在build目录下
*/

#在前面的命令中，make携带的参数为all,所以此时生成这里的all目标，而all又依赖于$(IMAGE_BIN)即1c102_demo.bin，所以此时进行该目标的生成。  
all : $(IMAGE_BIN)
#这里即是1c102_demo.bin的生成规则。它的依赖项为$(LS1C1X_OBJ)，依赖项的内容在上面有说明。  
$(IMAGE_BIN):$(LS1C1X_OBJ)
    #将所有生成的.o文件进行连接，此时生成的文件是elf文件
    $(LD) $(LD_OPTS) -o $(IMAGE_ELF) $^ -Map $(IMAGE_MAP)
    #$(STRIP) $(IMAGE_ELF)
    #将生成的elf文件转换为二进制bin文件
    $(OBJCOPY) -O binary $(IMAGE_ELF) $(IMAGE_BIN)
    #此操作会打印出生成镜像的各段的大小分布情况以及总大小
    $(SIZE) $(IMAGE_ELF)
    #这里会将生成的elf文件进行反汇编，生成的文件可以帮助我们后续进行调试
    $(OBJDUMP) -alD $(IMAGE_ELF) > $(IMAGENAME).s

$(OBJ_C) : %.o : %.c  
    $(CC) $(CC_COPTS) -c -o $@ $^
$(OBJ_S) : %.o : %.S
    $(CC) $(CC_OPTS) -c -o $@ $^

Czitong

写在结尾

特别鸣谢笔者的同事@snow与我一起完成了以上内容，同时也欢迎对龙芯有兴趣或者正在使用龙芯MCU的同志与我们一起交流，共建龙芯生态。

鄂ICP备2022017735号

此论坛为纯技术类论坛, 且为"独立运作，风险自控", 请用户在论坛中不要讨论无关话题, 以免影响论坛正常运行